Fix dialyzer opaqueness warnings on module attrs in OTP28

lib/elixir/lib/kernel.ex

@@ -3858,7 +3858,9 @@ defmodule Kernel do
 
   defp do_at_escape(name, value) do
     try do
-      :elixir_quote.escape(value, :none, false)
+      # mark module attrs as shallow-generated since the ast for their representation
+      # might contain opaque terms
+      Macro.escape(value, generated: true)
     rescue
       ex in [ArgumentError] ->
         raise ArgumentError,

lib/elixir/lib/macro.ex

@@ -808,6 +808,10 @@ defmodule Macro do
       nodes. Note this option changes the semantics of escaped code and
       it should only be used when escaping ASTs. Defaults to `false`.
 
+    * `:generated` - (since v1.19.0) Whether the AST should be considered as generated
+      by the compiler or not. This means the compiler and tools like Dialyzer may not
+      emit certain warnings.
+
       As an example for `:prune_metadata`, `ExUnit` stores the AST of every
       assertion, so when an assertion fails we can show code snippets to users.
       Without this option, each time the test module is compiled, we would get a
@@ -908,7 +912,17 @@ defmodule Macro do
   def escape(expr, opts \\ []) do
     unquote = Keyword.get(opts, :unquote, false)
     kind = if Keyword.get(opts, :prune_metadata, false), do: :prune_metadata, else: :none
-    :elixir_quote.escape(expr, kind, unquote)
+    generated = Keyword.get(opts, :generated, false)
+
+    case :elixir_quote.escape(expr, kind, unquote) do
+      # mark module attrs as shallow-generated since the ast for their representation
+      # might contain opaque terms
+      {caller, meta, args} when generated and is_list(meta) ->
+        {caller, [generated: true] ++ meta, args}
+
+      ast ->
+        ast
+    end
   end
 
   # TODO: Deprecate me on Elixir v1.22

lib/elixir/test/elixir/fixtures/dialyzer/opaqueness.ex

@@ -4,11 +4,16 @@ defmodule Dialyzer.Opaqueness do
     set
   end
 
-  def foo() do
+  def inlined do
     # inlining of literals should not violate opaqueness check
     bar(MapSet.new([1, 2, 3]))
   end
 
+  @my_set MapSet.new([1, 2, 3])
+  def module_attr do
+    bar(@my_set)
+  end
+
   # Task.Supervisor returns a Task.t() containing an opaque Task.ref()
   @spec run_task() :: Task.t()
   def run_task do

lib/elixir/test/elixir/macro_test.exs

@@ -84,6 +84,11 @@ defmodule MacroTest do
       assert Macro.escape(contents, unquote: true) == {:x, [], MacroTest}
     end
 
+    test "with generated" do
+      assert Macro.escape(%{a: {}}, generated: true) ==
+               {:%{}, [generated: true], [a: {:{}, [], []}]}
+    end
+
     defp eval_escaped(contents) do
       {eval, []} = Code.eval_quoted(Macro.escape(contents, unquote: true))
       eval